VBAでHTTPリクエストを使用して静的サイトをスクレイピング

Rem Http.cls
Option Explicit

Private HttpObj As Object
Private Declare Sub Sleep Lib "kernel32" (ByVal ms As Long)

Private Sub Class_Initialize()
Rem コメント部は切り替え用。分からないうちは切り替えずに使いましょう。
    Set HttpObj = CreateObject("Msxml2.ServerXMLHTTP.6.0")
    'Set HttpObj = CreateObject("MSXML2.XMLHTTP")
    'Set HttpObj = CreateObject("WinHttp.WinHttpRequest.5.1")
End Sub

Private Sub Class_Terminate()
    Set HttpObj = Nothing
End Sub

Public Function Send(url, Optional IsPOST As Boolean = False, Optional data = vbEmpty) As Boolean
On Error GoTo HasErr
    Sleep 2000 'スクレイピングのマナー(1000以上を設定のこと)
    With HttpObj
        .Open IIf(IsPOST, "POST", "GET"), url, False
        .setRequestHeader "Content-Type", "application/x-www-form-urlencoded"
        .setRequestHeader "Connection", "Keep-Alive"
        .setRequestHeader "Accept-encoding", "identity"
        .setRequestHeader "User-Agent", "Mozilla/5.0 (Windows NT 10.0; Win64; x64) AppleWebKit/537.36 (KHTML, like Gecko) Chrome/84.0.4147.135 Safari/537.36"
        .Send data
        DoEvents
        If .Status <> 200 Then GoTo HasErr
    End With
    Send = True
    Exit Function
HasErr:
    Send = False
End Function

Public Sub openHtmlOnBrowser(Optional Charset As String = "UTF-8")
    Dim Filename As String
    Filename = CreateObject("WScript.Shell").SpecialFolders("Desktop") & Chr(92) & "tmp_" & Format(Now, "HHMMSS") & ".html"
    With CreateObject("ADODB.Stream")
        .Charset = Charset
        .Open
        .WriteText HttpObj.responseText, 1
        .SaveToFile Filename, 2
        .Close
    End With
    Dim cmd As String: cmd = "explorer " & Chr(34) & Filename & Chr(34)
    CreateObject("WScript.Shell").Run cmd
    If MsgBox("Delete file?", vbYesNo + vbQuestion) = vbYes Then
        CreateObject("Scripting.FileSystemObject").DeleteFile Filename
    End If
End Sub

Option Explicit

Sub test()
    Dim Http As Http: Set Http = New Http

    Rem トップページにアクセス
    Http.Send ("https://www.e-typing.ne.jp/")
    Http.openHtmlOnBrowser

    Rem POSTデータの設定
    Dim UserName, Password
    UserName = "自分のメールアドレスを入れる"
    Password = "自分のパスワードを入れる"
    Dim data As String
    data = "f_em=" & UserName & "&f_pw=" & Password

    Rem ログイン処理
    Call Http.Send("https://www.e-typing.ne.jp/login/login.asp", True, data)
    Http.openHtmlOnBrowser
End Sub